dnl Process this file with autoconf to produce a configure script.
dnl
dnl Change the version number here
AC_INIT([Evolving Objects], [1.0.1], [eodev-help@sourceforge.net], [eo])
AC_PREREQ(2.53)

dnl make sure we are compiling from the correct sources
AC_CONFIG_SRCDIR(src/eoOp.h)

dnl define host, build, and target machine
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

dnl automake initialization
AM_INIT_AUTOMAKE([gnu dist-bzip2 dist-zip])
AM_CONFIG_HEADER(config.h)

dnl Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_RANLIB
AC_PATH_PROG([AR], [ar], [false], [$PATH:/usr/ccs/bin]) # solaris-x86 needs extra path
AC_ARG_VAR([DOXYGEN], [automatic documentation generation])
AC_CHECK_PROGS([DOXYGEN], [doxygen], [true])

dnl Checks for header files.
AC_LANG(C++)
AC_HEADER_STDC

dnl Checks for typedefs, structures, and compiler characteristics.
AC_CHECK_TYPES(uint32_t, [], AC_MSG_WARN([Need uint32_t from C99 standard.]))
AC_TYPE_SIZE_T

dnl Checks for libraries and library functions.
AC_CHECK_LIB(m, cos)


dnl Check for C++ library yaml-cpp (AC_CHEC_LIB only supports checking for C libraries)
AC_MSG_CHECKING('libyaml-cpp available')
AC_LANG(C++)
SAVED_LDFLAGS=$LDFLAGS
LDFLAGS="$LDFLAGS -lyaml-cpp"
AC_LINK_IFELSE(
    [AC_LANG_PROGRAM([#include <yaml-cpp/yaml.h>], [YAML::Emitter  dummy])],
        [ AC_MSG_RESULT([yes])
          SAVED_LDFLAGS="$SAVED_LDFLAGS -lyaml-cpp"
          AC_DEFINE(HAVE_LIBYAML_CPP,1,[Define to 1 if you have libyaml-cpp installed]) ],
        [AC_MSG_RESULT([no])])
LDFLAGS=$SAVED_LDFLAGS



dnl user-switches
AC_APPLICATIONS
AC_DEBUG
AC_GNUPLOT
AC_TUTORIAL

dnl create makefiles
AC_OUTPUT(Makefile \
          app/Makefile \
          app/mastermind/Makefile \
          app/gprop/Makefile \
          app/gpsymreg/Makefile \
          contrib/Makefile \
          doc/Makefile \
          src/Makefile \
          src/do/Makefile \
          src/es/Makefile \
          src/gp/Makefile \
          src/ga/Makefile \
          src/other/Makefile \
          src/utils/Makefile \
          src/moo/Makefile \
          test/Makefile \
          tutorial/Makefile \
          tutorial/html/Makefile \
          tutorial/Lesson1/Makefile \
          tutorial/Lesson2/Makefile \
          tutorial/Lesson3/Makefile \
          tutorial/Lesson4/Makefile \
          tutorial/Lesson5/Makefile \
          tutorial/Templates/Makefile \
          tutorial/pdf/Makefile)